Сохраните текст как BAT файл с любым именем например SketchUp_save.bat
После запуска он сохранить три ветки реестра с настройками панелей и включенных/выключеных плагинов в файл registry.reg
Все теперь двойным кликом по нему вы загрузите состояние панелек и плагинов. Если они вдруг слетели.
Переименуйте его как угодно если хотите иметь несколько таких файлов.
Код:
@echo off
set "branch=HKEY_CURRENT_USER\Software\SketchUp\SketchUp 2017\"
set "soft_1=RubyWorkspace"
set "soft_2=Workspace"
set "soft_3=Extensions"
reg add "%branch%$$$" /f>nul
reg export "%branch%$$$" "registry.reg" /y>nul
reg delete "%branch%$$$" /f>nul
(
for %%i in (
"[-%branch%$$$]"
""
"[-%branch%%soft_1%]"
""
"[-%branch%%soft_2%]"
""
"[-%branch%%soft_3%]"
""
) do (
cmd /u /c echo.%%~i
)
)>>"registry.reg"
for %%i in (
"%soft_1%"
"%soft_2%"
"%soft_3%"
) do (
reg export "%branch%%%~i" 1.reg /y
copy "registry.reg"+1.reg 2.reg>nul
move 2.reg "registry.reg">nul
)
del 1.reg
ping -n 3 localhost>nul
exit /b
© по материалам этой ветки
http://forum.oszone.net/thread-286800-2.html